$upper()

DESCRIPTION
    returns a string all in upper case

SYNOPSIS
    $upper(s)

ARGUMENTS
    s - a quoted string, or string expression

EXAMPLES

# pikt +C 'output $upper("shoot louder, louder... i don$squote()t understand")'
SHOOT LOUDER, LOUDER... I DON'T UNDERSTAND

        rule
                =output_alarm_log($upper($inlin))

        rule    // page if greater than or equal to higher threshold,
                // but only once every hour
                if #envtemp >= #pagelim[#unit]
                        set $pagemsg = $upper("AC$text(#unit): envtemp $text(#envtemp) >=
                                                               pagelim $text(#pagelim[#unit])!")
                        =hourly(=page($pagemsg, =pageaddr, =allhours(#now())), )
                fi

        rule    // initialize down message
                set $dnmsg = $host . $upper("is down")

        ...

        rule    // page, but only periodically, if highest-level alert
                if =highestlevelalert
                        =hourly(=page($dnmsg, =pageaddr, =allhours(#now())), )
                fi

        rule    // for all systems, always report new downages
                if $state ne %state
                        output mail $dnmsg
                        next
                fi

        rule    // for missioncritical systems, report continuing downages,
                // but only periodically
                if #misscrit
                        =every_four_hours(output mail $dnmsg, )
                        if =highestlevelalert
                                =hourly(=output_other_mail(SYSDOWN, 'PIKT SysDown',
                                                           =sysadmins, $dnmsg), )
                        fi
                        next
                fi

        rule    // non-root uid 0's
                if    $uid eq "0"
                   && $user !~ "^(root|sundiag|sysdiag|smtp)$"
                        output mail "USER " . $upper($user) . " HAS UID OF 0!"
                        output syslog "USER " . $upper($user) . " HAS UID OF 0!"
                endif

        rule    // no password
                if $password eq ""
                        output mail $upper("user " . $user . " has no password!")
                        output syslog $upper("user " . $user . " has no password!")
                endif

SEE ALSO
    $lower()
    $proper()

    String Functions
    Numerical Functions